flex & bison: chapter 3

flex_bison/3/Makefile

+SUBDIRS = calc0 calc1
+
+.PHONY: all clean
+all:
+	for x in $(SUBDIRS); do $(MAKE) -C "$$x"; done
+clean:
+	for x in $(SUBDIRS); do $(MAKE) -C "$$x" clean; done

flex_bison/3/calc0/Makefile

+BIN = calc
+LDLIBS = -lfl
+
+%.tab.c %.tab.h: %.y
+	bison -d $<
+
+.PHONY: all clean
+all: $(BIN)
+lex.c: calc.h calc.tab.h
+calc_c.o: calc.h calc.tab.h
+calc: lex.o calc_c.o
+clean:
+	rm -f $(BIN) calc.c calc.tab.[hc] lex.[co] calc_c.o

flex_bison/3/calc0/calc.h

+extern int yylineno;
+int yylex(void);
+int yyparse(void);
+void yyerror(char *s, ...);
+
+struct ast {
+    int nodetype;
+    struct ast *l, *r;
+};
+
+struct numval {
+    int nodetype;
+    double number;
+};
+
+struct ast *newast(int nodetype, struct ast *l, struct ast *r);
+struct ast *newnum(double d);
+double eval(struct ast *a);
+void treefree(struct ast *a);

flex_bison/3/calc0/calc.y

+%{
+#include <stdio.h>
+#include <stdlib.h>
+
+#include "calc.h"
+%}
+
+%union {
+    struct ast *a;
+    double d;
+}
+
+%token <d> NUMBER
+%token EOL
+
+%type <a> exp factor term
+
+%%
+
+calclist:
+    | calclist exp EOL {
+        printf("= %4.4g\n", eval($2));
+        treefree($2);
+        printf("> ");
+    }
+    | calclist EOL { printf("> "); }
+    ;
+
+exp: factor
+    | exp '+' factor { $$ = newast('+', $1, $3); }
+    | exp '-' factor { $$ = newast('-', $1, $3); }
+    ;
+
+factor: term
+    | factor '*' term { $$ = newast('*', $1, $3); }
+    | factor '/' term { $$ = newast('/', $1, $3); }
+    ;
+
+term: NUMBER { $$ = newnum($1); }
+    | '|' term { $$ = newast('|', $2, NULL); }
+    | '(' exp ')' { $$ = $2; }
+    | '-' term { $$ = newast('M', $2, NULL); }
+    ;
+
+%%

flex_bison/3/calc0/calc_c.c

+#include <stdarg.h>
+#include <stdio.h>
+#include <stdlib.h>
+
+#include "calc.h"
+
+struct ast *newast(int nodetype, struct ast *l, struct ast *r) {
+    struct ast *ret = malloc(sizeof(*ret));
+    if(!ret) {
+        yyerror("out of space");
+        exit(1);
+    }
+    *ret = (struct ast){
+        .nodetype = nodetype,
+        .l = l,
+        .r = r,
+    };
+    return ret;
+}
+
+struct ast *newnum(double d) {
+    struct numval *ret = malloc(sizeof(*ret));
+    if(!ret) {
+        yyerror("out of space");
+        exit(1);
+    }
+    *ret = (struct numval){
+        .nodetype = 'K',
+        .number = d,
+    };
+    return (struct ast*)ret;
+}
+
+double eval(struct ast *a) {
+    switch(a->nodetype) {
+    case 'K': return ((struct numval*)a)->number;
+    case '+': return eval(a->l) + eval(a->r);
+    case '-': return eval(a->l) - eval(a->r);
+    case '*': return eval(a->l) * eval(a->r);
+    case '/': return eval(a->l) / eval(a->r);
+    case '|': double v = eval(a->l); return v < 0 ? -v : v;
+    case 'M': return -eval(a->l);
+    default:
+        fprintf(stderr, "internal error: bad node %c\n", a->nodetype);
+        return 0;
+    }
+}
+
+void treefree(struct ast *a) {
+    switch(a->nodetype) {
+    case '+':
+    case '-':
+    case '*':
+    case '/': treefree(a->r); [[fallthrough]]
+    case '|':
+    case 'M': treefree(a->l); [[fallthrough]]
+    case 'K': free(a); break;
+    default: fprintf(stderr, "internal error: free bad node %c\n", a->nodetype);
+    }
+}
+
+void yyerror(char *s, ...) {
+    va_list ap;
+    va_start(ap, s);
+    fprintf(stderr, "%d: error: ", yylineno);
+    vfprintf(stderr, s, ap);
+    fputc('\n', stderr);
+}
+
+int main(void) {
+    printf("> ");
+    return yyparse();
+}

flex_bison/3/calc0/lex.l

+%option noyywrap nodefault yylineno
+%{
+#include "calc.h"
+#include "calc.tab.h"
+%}
+
+EXP ([Ee][+-]?[0-9]+)
+
+%%
+
+"+" |
+"-" |
+"*" |
+"/" |
+"|" |
+"(" |
+")" { return *yytext; }
+
+[0-9]+"."[0-9]*{EXP}? |
+"."?[0-9]+{EXP}? { yylval.d = atof(yytext); return NUMBER; }
+
+\n { return EOL; }
+"//".*
+[ \t]
+. { yyerror("Mystery character %c\n", *yytext); }
+
+%%

flex_bison/3/calc1/Makefile

+../calc0/Makefile
\ No newline at end of file

flex_bison/3/calc1/calc.h

+../calc0/calc.h
\ No newline at end of file

flex_bison/3/calc1/calc.y

+%{
+#include <stdio.h>
+#include <stdlib.h>
+
+#include "calc.h"
+%}
+
+%union {
+    struct ast *a;
+    double d;
+}
+
+%token <d> NUMBER
+%token EOL
+
+%left '+' '-'
+%left '*' '/'
+%nonassoc '|' UMINUS
+
+%type <a> exp
+
+%%
+
+calclist:
+    | calclist exp EOL {
+        printf("= %4.4g\n", eval($2));
+        treefree($2);
+        printf("> ");
+    }
+    | calclist EOL { printf("> "); }
+    ;
+
+exp:  exp '+' exp { $$ = newast('+', $1, $3); }
+    | exp '-' exp { $$ = newast('-', $1, $3); }
+    | exp '*' exp { $$ = newast('*', $1, $3); }
+    | exp '/' exp { $$ = newast('/', $1, $3); }
+    | '|' exp     { $$ = newast('|', $2, NULL); }
+    | NUMBER      { $$ = newnum($1); }
+    | '-' exp %prec UMINUS { $$ = newast('M', $2, NULL); }
+    | '(' exp ')' { $$ = $2; }
+    ;
+
+%%

flex_bison/3/calc1/calc_c.c

+../calc0/calc_c.c
\ No newline at end of file

flex_bison/3/calc1/lex.l

+../calc0/lex.l
\ No newline at end of file

flex_bison/Makefile

-SUBDIRS = 1 2
+SUBDIRS = 1 2 3
 
 .PHONY: all clean
 all: